NAME

DBI - Database independent interface for Perl

SYNOPSIS

  use DBI;
 
  @driver_names = DBI->available_drivers;
  @data_sources = DBI->data_sources($driver_name);


  $dbh = DBI->connect($data_source, $username, $auth);
  $dbh = DBI->connect($data_source, $username, $auth, \%attr);
 
  $rv  = $dbh->do($statement);
  $rv  = $dbh->do($statement, \%attr);
  $rv  = $dbh->do($statement, \%attr, @bind_values);


  @row_ary = $dbh->selectrow_array($statement);
  $ary_ref = $dbh->selectall_arrayref($statement);
 
  $sth = $dbh->prepare($statement);
  $sth = $dbh->prepare_cached($statement);
 
  $rv = $sth->bind_param($p_num, $bind_value);
  $rv = $sth->bind_param($p_num, $bind_value, $bind_type);
  $rv = $sth->bind_param($p_num, $bind_value, \%attr);


  $rv = $sth->execute;
  $rv = $sth->execute(@bind_values);
 
  $rc = $sth->bind_col($col_num, \$col_variable);
  $rc = $sth->bind_columns(\%attr, @list_of_refs_to_vars_to_bind);


  @row_ary  = $sth->fetchrow_array;
  $ary_ref  = $sth->fetchrow_arrayref;
  $hash_ref = $sth->fetchrow_hashref;
 
  $ary_ref  = $sth->fetchall_arrayref;


  $rv = $sth->rows;
 
  $rc  = $dbh->commit;
  $rc  = $dbh->rollback;


  $sql = $dbh->quote($string);
 
  $rc  = $h->err;
  $str = $h->errstr;
  $rv  = $h->state;


  $rc  = $dbh->disconnect;

NOTE

This is the DBI specification that corresponds to the DBI version 1.06 ($Date: 1999/01/06 13:07:22 $).

The DBI specification is currently evolving quite quickly so it is important to check that you have the latest copy. The RECENT CHANGES section below has a summary of user-visible changes and the Changes file supplied with the DBI holds more detailed change information.

Note also that whenever the DBI changes the drivers take some time to catch up. Recent versions of the DBI have added many new features (marked *NEW* in the text) that may not yet be supported by the drivers you use. Talk to the authors of those drivers if you need the features.

Please also read the DBI FAQ which is installed as a DBI::FAQ module so you can use perldoc to read it by executing the perldoc DBI::FAQ command.

RECENT CHANGES

A brief summary of significant user-visible changes in recent versions (if a recent version isn't mentioned it simply means that there were no significant user-visible changes in that version).

DBI 1.00 - 14th August 1998

Added $dbh->table_info.

DBI 0.96 - 10th August 1998

Added $sth->{PRECISION} and $sth->{SCALE}. Added DBD::Shell and dbish interactive DBI shell. Any database attribs can be set via DBI->connect(,,, \%attr). Added _get_fbav and _set_fbav methods for Perl driver developers. DBI trace now shows appends `` at yourfile.pl line nnn''. PrintError and RaiseError now prepend driver and method name. Added $dbh->{Name}. Added $dbh->quote($value, $data_type). Added DBD::Proxy and DBI::ProxyServer (from Jochen Wiedmann). Added $dbh->selectall_arrayref and $dbh->selectrow_array methods. Added $dbh->table_info. Added $dbh->type_info and $dbh->type_info_all. Added $h->trace_msg($msg) to write to trace log. Added @bool = DBI::looks_like_number(@ary).

DBI 0.92 - 4th February 1998

Added $dbh->prepare_cached() caching variant of $dbh->prepare. Added new attributes: Active, Kids, ActiveKids, CachedKids. Added support for general-purpose 'private_' attributes.

DESCRIPTION

The Perl DBI is a database access Application Programming Interface (API) for the Perl Language. The DBI defines a set of functions, variables and conventions that provide a consistent database interface independant of the actual database being used.

DBI is a database Application Programming Interface (API) written in the form of a Perl5 module. This module defines a set of "methods" and "attributes" to use that defines a consistent interface to any database that has a DataBase Driver (DBD) defined. This driver also takes the form of a Perl5 module. The DBI acts as a "switch " between a programmer's application and one or more database drivers. It is the drivers that actually talk to the database. For MySQL, this driver is called DBD::mysql. These methods and attributes are devided into database methods and attributes and statement methods and attributes. For more information on the Perl5 DBI, please visit http://www.symbolstone.org/technology/perl/DBI/index.html and read the documentation. For more information on Object Oriented Programming (OOP) as defined in Perl5, go to http://language.perl.com/info/documentation.html . Your best bet as always is to read the documentation that comes with the modules! This documentation is embedded in the modules themselves using POD (Plain Old Documentation) syntax. You can read this format several ways.

1. Just type: perldoc DBI and/or perldoc mysql
2. Use the POD converters: pod2man, pod2html, pod2text, pod2laytex
i.e. pod2html DBI
Last but not least, the modules tar file you downloaded has excellent code examples used to test the modules installation. Usually found in the ./t directory (relative to the directory you untar'd it in).

It is important to remember that the DBI is just an interface. A thin layer of 'glue' between an application and one or more Database Drivers. It is the drivers which do the real work. The DBI provides a standard interface and framework for the drivers to operate within.

 

Architecture of a DBI Application

             |<- Scope of DBI ->|
                  .-.   .--------------.   .-------------.
  .-------.       | |---| XYZ Driver   |---| XYZ Engine  |
  | Perl  |       |S|   `--------------'   `-------------'
  | script|  |A|  |w|   .--------------.   .-------------.
  | using |--|P|--|i|---|Oracle Driver |---|Oracle Engine|
  | DBI   |  |I|  |t|   `--------------'   `-------------'
  | API   |       |c|...
  |methods|       |h|... Other drivers
  `-------'       | |...
                  `-'

The API is the Application Perl-script (or Programming) Interface. The call interface and variables provided by DBI to perl scripts. The API is implemented by the DBI Perl extension.

The 'Switch' is the code that 'dispatches' the DBI method calls to the appropriate Driver for actual execution. The Switch is also responsible for the dynamic loading of Drivers, error checking/handling and other duties. The DBI and Switch are generally synonymous.

The Drivers implement support for a given type of Engine (database). Drivers contain implementations of the DBI methods written using the private interface functions of the corresponding Engine. Only authors of sophisticated/multi-database applications or generic library functions need be concerned with Drivers.

Notation and Conventions

  DBI     static 'top-level' class name
  $dbh    Database handle object
  $sth    Statement handle object
  $drh    Driver handle object (rarely seen or used in applications)
  $h      Any of the $??h handle types above
  $rc     General Return Code  (boolean: true=ok, false=error)
  $rv     General Return Value (typically an integer)
  @ary    List of values returned from the database, typically a row of data
  $rows   Number of rows processed (if available, else -1)
  $fh     A filehandle
  undef   NULL values are represented by undefined values in perl
  \%attr  Reference to a hash of attribute values passed to methods

Note that Perl will automatically destroy database and statement objects if all references to them are deleted.

Handle object attributes are shown as:

<PRE> $h-E&lt;gt&gt;{attribute_name} </PRE> (type)

where type indicates the type of the value of the attribute (if it's not a simple scalar): 

  \$   reference to a scalar: $h->{attr}       or  $a = ${$h->{attr}}
  \@   reference to a list:   $h->{attr}->[0]  or  @a = @{$h->{attr}}
  \%   reference to a hash:   $h->{attr}->{a}  or  %a = %{$h->{attr}}

General Interface Rules & Caveats

The DBI does not have a concept of a `current session'. Every session has a handle object (i.e., a $dbh) returned from the connect method and that handle object is used to invoke database related methods.

Most data is returned to the perl script as strings (null values are returned as undef). This allows arbitrary precision numeric data to be handled without loss of accuracy. Be aware that perl may not preserve the same accuracy when the string is used as a number.

Dates and times are returned as character strings in the native format of the corresponding Engine. Time Zone effects are Engine/Driver dependent.

Perl supports binary data in perl strings and the DBI will pass binary data to and from the Driver without change. It is up to the Driver implementors to decide how they wish to handle such binary data.

Multiple SQL statements may not be combined in a single statement handle, e.g., a single $sth.

Non-sequential record reads are not supported in this version of the DBI. E.g., records can only be fetched in the order that the database returned them and once fetched they are forgotten.

Positioned updates and deletes are not directly supported by the DBI. See the description of the CursorName attribute for an alternative.

Individual Driver implementors are free to provide any private functions and/or handle attributes that they feel are useful. Private driver functions can be invoked using the DBI func method. Private driver attributes are accessed just like standard attributes.

Many methods have an optional \%attr parameter which can be used to pass information to the driver implementing the method. Except where specifically documented the \%attr parameter can only be used to pass driver specific hints. In general you can ignore \%attr parameters or pass it as undef.

Character sets: Most databases which understand character sets have a default global charset and text stored in the database is, or should be, stored in that charset (if it's not then that's the fault of either the database or the application that inserted the data). When text is fetched it should be (automatically) converted to the charset of the client (presumably based on the locale). If a driver needs to set a flag to get that behaviour then it should do so. It should not require the application to do that.

Naming Conventions and Name Space

The DBI package and all packages below it (DBI::*) are reserved for use by the DBI. Package names beginning with DBD:: are reserved for use by DBI database drivers. All environment variables used by the DBI or DBD's begin with 'DBI_' or 'DBD_'.

The letter case used for attribute names is significant and plays an important part in the portability of DBI scripts. The case of the attribute name is used to signify who defined the meaning of that name and its values. 

  Case of name  Has a meaning defined by
  ------------  ------------------------
  UPPER_CASE    Standards, e.g.,  X/Open, SQL92 etc (portable)
  MixedCase     DBI API (portable), underscores are not used.
  lower_case    Driver or Engine specific (non-portable)

It is of the utmost importance that Driver developers only use lowercase attribute names when defining private attributes. Private attribute names must be prefixed with the driver name or suitable abbreviation (e.g., ora_ for Oracle, ing_ for Ingres etc).

Driver Specific Prefix Registry: 

  dbm_     DBD::DBMaker
  ora_     DBD::Oracle
  ing_     DBD::Ingres
  odbc_    DBD::ODBC
  syb_     DBD::Sybase
  db2_     DBD::DB2
  ix_      DBD::Informix
  csv_     DBD::CSV
  file_    DBD::TextFile
  xbase_   DBD::XBase
  solid_   DBD::Solid
  proxy_   DBD::Proxy

Outline Usage

First you need to load the DBI module: 

  use DBI;

(also adding use strict; is recommended) then connect to your data source: 

  $dbh = DBI->connect($dsn, $user, $password,
                      { RaiseError => 1, AutoCommit => 0 });

The DBI allows an application to `prepare' statements for later execution. A prepared statement is identified by a statement handle object, e.g., $sth.

Typical method call sequence for a select statement: 

  prepare,
    execute, fetch, fetch, ...
    execute, fetch, fetch, ...
    execute, fetch, fetch, ...

for example: 

  $sth = $dbh->prepare("select foo, bar from table where baz=?");


  $sth->execute($baz);
  while(@row = $sth->fetchrow_array) {
    print "@row\n";
  }

Typical method call sequence for a non-select statement: 

  prepare,
    execute,
    execute,
    execute.

for example: 

  $sth = $dbh->prepare("insert into table(foo,bar,baz) values (?,?,?)");


  while(<CSV>) {
    chop;
    my ($foo,$bar,$baz) = split /,/;
        $sth->execute($foo,$bar,$baz);
  }

To commit your changes to the database (when AutoCommit is off): 

  $dbh->commit;  # or call $dbh->rollback; to undo changes

Finally, when you have finished working with the data source you should disconnect from it: 

  $dbh->disconnect;

Placeholders and Bind Values

Some drivers support Placeholders and Bind Values. These drivers allow a database statement to contain placeholders, sometimes called parameter markers, that indicate values that will be supplied later, before the prepared statement is executed. For example, an application might use the following to insert a row of data into the SALES table: 

  insert into sales (product_code, qty, price) values (?, ?, ?)

or the following, to select the description for a product: 

  select description from products where product_code = ?

The ? characters are the placeholders. The association of actual values with placeholders is known as binding and the values are referred to as bind values.

When using placeholders with the SQL LIKE qualifier you must remember that the placeholder substitutes for the whole string. So you should use ``... LIKE ? ...'' and include any wildcard characters in the value that you bind to the placeholder.

Null Values

Undefined values or undef can be used to indicate null values. However, care must be taken in the particular case of trying to use null values to qualify a select statement. Consider: 

  select description from products where product_code = ?

Binding an undef (NULL) to the placeholder will not select rows which have a NULL product_code! Refer to the SQL manual for your database engine or any SQL book for the reasons for this. To explicitly select NULLs you have to say ``where product_code is NULL'' and to make that general you have to say: 

  ... where (product_code = ? or (? is null and product_code is null))

and bind the same value to both placeholders.

Performance

Without using placeholders, the insert statement above would have to contain the literal values to be inserted and it would have to be re-prepared and re-executed for each row. With placeholders, the insert statement only needs to be prepared once. The bind values for each row can be given to the execute method each time it's called. By avoiding the need to re-prepare the statement for each row the application typically many times faster! Here's an example: 

  my $sth = $dbh->prepare(q{
    insert into sales (product_code, qty, price) values (?, ?, ?)
  }) || die $dbh->errstr;
  while (<>) {
      chop;
      my ($product_code, $qty, $price) = split /,/;
      $sth->execute($product_code, $qty, $price) || die $dbh->errstr;
  }
  $dbh->commit || die $dbh->errstr;

See execute and bind_param for more details.

The q{...} style quoting used in this example avoids clashing with quotes that may be used in the SQL statement. Use the double-quote like qq{...} operator if you want to interpolate variables into the string. See perlop for more details.

See bind_columns for a related method used to associate perl variables with the output columns of a select statement.

SQL - A Query Language

Most DBI drivers require applications to use a dialect of SQL (the Structured Query Language) to interact with the database engine. These links provide useful information and further links about SQL: 

  http://www.geocities.com/ResearchTriangle/Node/9672/sqltut.html
  http://www.contrib.andrew.cmu.edu/~shadow/sql.html

The DBI itself does not mandate or require any particular language to be used. It is language independant. In ODBC terms the DBI is in 'pass-thru' mode (individual drivers might not be). The only requirement is that queries and other statements must be expressed as a single string of letters passed as the first argument to the prepare method.

THE DBI CLASS

DBI Class Methods

connect 

  $dbh = DBI->connect($data_source, $username, $password) || die $DBI::errstr;
  $dbh = DBI->connect($data_source, $username, $password, \%attr) || die $DBI::errstr;

Establishes a database connection (session) to the requested data_source. Returns a database handle object if the connect succeeds. Use $dbh->disconnect to terminate the connection.

If the connect fails (see below) it returns undef and sets $DBI::err and $DBI::errstr (it does not set $! etc). Generally you should test the return status of connect and print $DBI::errstr if it has failed.

Multiple simultaneous connections to multiple databases through multiple drivers can be made via the DBI. Simply make one connect call for each and keep a copy of each returned database handle.

The $data_source value should begin with 'dbi:driver_name:'. That prefix will be stripped off and the driver_name part is used to specify the driver (letter case is significant).

As a convenience, if the $data_source field is undefined or empty the DBI will substitute the value of the environment variable DBI_DSN. If the driver_name part is empty (i.e., data_source prefix is 'dbi::') the environment variable DBI_DRIVER is used. If that variable is not set then the connect dies.

Examples of $data_source values: 

  dbi:DriverName:database_name
  dbi:DriverName:database_name@hostname:port
  dbi:DriverName:database=database_name;host=hostname;port=port

There is no standard for the text following the driver name. Each driver is free to use whatever syntax it wants. The only requirement the DBI makes is that all the information is supplied in a single string. You must consult the documentation for the drivers you are using for a description of the syntax they require. (Where a driver author needs to define a syntax for the data_source it is recommended that they follow the ODBC style, the last example above.)

If the environment variable DBI_AUTOPROXY is defined (and the driver in $data_source is not 'Proxy') then the connect request will automatically be changed to: 

  dbi:Proxy:$ENV{DBI_AUTOPROXY};dsn=$data_source

and passed to the DBD::Proxy module. DBI_AUTOPROXY would typically be ``hostname=...;port=...''. See Proxy for more details.

If $username or $password are undefined (rather than empty) then the DBI will substitute the values of the DBI_USER and DBI_PASS environment variables respectively. The use of the environment for these values is not recommended for security reasons. The mechanism is only intended to simplify testing. 

#!/usr/bin/perl -w
use DBI;

my $dbh=DBI->connect( )
        or die "Database connection not made:$DBI::errstr\n";
print "Connect OK!!";
$dbh->disconnect();

DBI->connect automatically installs the driver if it has not been installed yet. Driver installation always returns a valid driver handle or it dies with an error message which includes the string 'install_driver' and the underlying problem. So, DBI->connect will die on a driver installation failure and will only return undef on a connect failure, for which $DBI::errstr will hold the error.

The $data_source argument (with the 'dbi:...:' prefix removed) and the $username and $password arguments are then passed to the driver for processing. The DBI does not define any interpretation for the contents of these fields. The driver is free to interpret the data_source, username and password fields in any way and supply whatever defaults are appropriate for the engine being accessed (Oracle, for example, uses the ORACLE_SID and TWO_TASK env vars if no data_source is specified).

The AutoCommit and PrintError attributes for each connection default to default to on (see AutoCommit and PrintError for more information).

The \%attr parameter can be used to alter the default settings of the PrintError, RaiseError, AutoCommit and other attributes. For example: 

  $dbh = DBI->connect($data_source, $user, $pass, {
        PrintError => 0,
        AutoCommit => 0
  });

Portable applications should not assume that a single driver will be able to support multiple simultaneous sessions.

Where possible each session ($dbh) is independent from the transactions in other sessions. This is useful where you need to hold cursors open across transactions, e.g., use one session for your long lifespan cursors (typically read-only) and another for your short update transactions.

For compatibility with old DBI scripts the driver can be specified by passing its name as the fourth argument to connect (instead of \%attr): 

  $dbh = DBI->connect($data_source, $user, $pass, $driver);
In this 'old-style' form of connect the $data_source should not start with 'dbi:driver_name:' and, even if it does, the embedded driver_name will be ignored. The $dbh->{AutoCommit} attribute is undefined. The $dbh->{PrintError} attribute is off. And the old DBI_DBNAME env var is checked if DBI_DSN is not defined. This 'old-style' connect will be withdrawn in a future version. 
#!/usr/bin/perl -w
use DBI;
my $database = "DBSAMPLE";		   # Database name
my $data_source = "DBI:DBMaker:$database"; # Datasource
my $username = "SYSADM";		   # User name
my $password = "";			   # Password
my $dbh = DBI->connect( $data_source, $username, $password)
          or die "Can't connect to $data_source: $DBI::errstr\n";
print "Connect to $database OK.";
$dbh->disconnect;
available_drivers 

  @ary = DBI->available_drivers;
  @ary = DBI->available_drivers($quiet);

Returns a list of all available drivers by searching for DBD::* modules through the directories in @INC. By default a warning will be given if some drivers are hidden by others of the same name in earlier directories. Passing a true value for $quiet will inhibit the warning. 

#!/usr/bin/perl -w
use strict;
use DBI;

# Returns a list of all available drivers by searching for DBD::*
my @ary = DBI->available_drivers;
print "________________________\n";
print " Available DBD::Drivers\n";
print "________________________\n";
foreach $driver (@ary){ 
	print "$driver\n";
}
print "________________________\n";
data_sources 

  @ary = DBI->data_sources($driver);
  @ary = DBI->data_sources($driver, \%attr);

Returns a list of all data sources (databases) available via the named driver. The driver will be loaded if not already. If $driver is empty or undef then the value of the DBI_DRIVER environment variable will be used. 

#!/usr/bin/perl -w
use strict;
use DBI;

my @db = DBI->data_sources();
foreach my $b (@db) {
  print "$b\n";
}

Data sources will be returned in a form suitable for passing to the connect method, i.e., they will include the ``dbi:$driver:'' prefix.

Note that many drivers have no way of knowing what data sources might be available for it and thus, typically, return an empty or incomplete list. 

#!/usr/bin/perl -w
use strict;
use DBI;

my @drivers = DBI->available_drivers;
foreach my $d (@drivers){
  print "_____________________\n";
  print "$d:\n";
  print "_____________________\n";
  my @db = DBI->data_sources($d);
  foreach my $b (@db) {
    print "$b\n";
  }
}
trace 

  DBI->trace($trace_level)
  DBI->trace($trace_level, $trace_file)

DBI trace information can be enabled for all handles using this DBI class method. To enable trace information for a specific handle use the similar $h->trace method described elsewhere.

Use $trace_level 2 to see detailed call trace information including parameters and return values. The trace output is detailed and typically very useful. Much of the trace output is formatted using the neat function and thus strings in the trace output may be edited and truncated by it.

Use $trace_level 0 to disable the trace.

Initially trace output is written to STDERR. If $trace_filename is specified then the file is opened in append mode and all trace output (including that from other handles) is redirected to that file. Further calls to trace without a $trace_filename do not alter where the trace output is sent. 

#!/usr/bin/perl -w
use DBI;
use strict;

DBI->trace(2);
my $dbh = DBI->connect("DBI:DBMaker:DBSAMPLE","SYSADM","")
          or die "Unable to connect to Database: $DBI::errstr\n";

DBI->trace(2,"trace.txt");

my $sth = $dbh->prepare("SELECT * FROM SYSUSER");
$sth->execute or die "Unable to execute query: $dbh->errstr\n";
$sth->finish;
$dbh->disconnect;

DBI->trace(0,"trace.txt");

See also the $h->trace() method and DEBUGGING for information about the DBI_TRACE environment variable.

DBI Utility Functions

neat 

  $str = DBI::neat($value, $maxlen);

Return a string containing a neat (and tidy) representation of the supplied value.

Strings will be quoted (but internal quotes will not be escaped). Values known to be numeric will be unquoted. Undefined (NULL) values will be shown as undef (without quotes). Unprintable characters will be replaced by dot (.).

For result strings longer than $maxlen the result string will be truncated to $maxlen-4 and ...' will be appended. If $maxlen is 0 or undef it defaults to $DBI::neat_maxlen which, in turn, defaults to 400.

This function is designed to format values for human consumption. It is used internally by the DBI for trace output. It should typically not be used for formating values for database use (see also quote).

neat_list 

  $str = DBI::neat_list(\@listref, $maxlen, $field_sep);

Calls DBI::neat on each element of the list and returns a string containing the results joined with $field_sep. $field_sep defaults to ", ".

looks_like_number 

  @bool = DBI::looks_like_number(@array);

Returns true for each element that looks like a number. Returns false for each element that does not look like a number. Returns undef for each element that is undefined or empty.

DBI Dynamic Attributes

These attributes are always associated with the last handle used.

Where an attribute is equivalent to a method call, then refer to the method call for all related documentation.

Warning: these attributes are provided as a convenience but they do have limitations. Specifically, because they are associated with the last handle used, they should only be used immediately after calling the method which 'sets' them. They have a 'short lifespan'. There may also be problems with the multi-threading in 5.005.

If in any doubt, use the corresponding method call.

$DBI::err

Equivalent to $h->err.

$DBI::errstr

Equivalent to $h->errstr.

$DBI::state

Equivalent to $h->state.

$DBI::rows

Equivalent to $h->rows.

METHODS COMMON TO ALL HANDLES

err 

  $rv = $h->err;

Returns the native database engine error code from the last driver function called.

errstr 

  $str = $h->errstr;

Returns the native database engine error message from the last driver function called.

state 

  $str = $h->state;

Returns an error code in the standard SQLSTATE five character format. Note that the specific success code 00000 is translated to 0 (false). If the driver does not support SQLSTATE then state will return S1000 (General Error) for all errors.

trace 

  $h->trace($trace_level);
  $h->trace($trace_level, $trace_filename);

DBI trace information can be enabled for a specific handle (and any future children of that handle) by setting the trace level using the trace method.

Use $trace_level 2 to see detailed call trace information including parameters and return values. The trace output is detailed and typically very useful.

Use $trace_level 0 to disable the trace.

Initially trace output is written to STDERR. If $trace_filename is specified then the file is opened in append mode and all trace output (including that from other handles) is redirected to that file. Further calls to trace without a $trace_filename do not alter where the trace output is sent.

See also the DBI->trace() method and DEBUGGING for information about the DBI_TRACE environment variable. The neat function is often used to format trace information and thus strings in the trace output may be edited and truncated by it.

trace_msg 

  $h->trace_msg($message_text);

Writes $message_text to trace file if trace is enabled for $h or for the DBI as a whole. Can also be called as DBI->trace_msg($msg). See trace.

func 

  $h->func(@func_arguments, $func_name);

The func method can be used to call private non-standard and non-portable methods implemented by the driver. Note that the function name is given as the last argument.

This method is not directly related to calling stored procedures. Calling stored procedures is currently not defined by the DBI. Some drivers, such as DBD::Oracle, support it in non-portable ways. See driver documentation for more details.

ATTRIBUTES COMMON TO ALL HANDLES

These attributes are common to all types of DBI handles.

Some attributes are inherited by child handles. That is, the value of an inherited attribute in a newly created statement handle is the same as the value in the parent database handle. Changes to attributes in the new statement handle do not affect the parent database handle and changes to the database handle do not affect existing statement handles, only future ones.

Attempting to set or get the value of an unknown attribute is fatal, except for private driver specific attributes (which all have names starting with a lowercase letter).

Example: 

  $h->{AttributeName} = ...;    # set/write
  ... = $h->{AttributeName};    # get/read
Warn (boolean, inherited)

Enables useful warnings for certain bad practices. Enabled by default. Some emulation layers, especially those for perl4 interfaces, disable warnings.

Active (boolean, read-only)

True if the handle object is 'active'. This is rarely used in applications. The exact meaning of active is somewhat vague at the moment. For a database handle it typically means that the handle is connected to a database ($dbh->disconnect should set Active off). For a statement handle it typically means that the handle is a select that may have more data to fetch ($dbh->finish or fetching all the data should set Active off).

Kids (integer, read-only)

For a driver handle, Kids is the number of currently existing database handles that were created from that driver handle. For a database handle, Kids is the number of currently existing statement handles that were created from that database handle.

ActiveKids (integer, read-only)

Like Kids (above), but only counting those that are Active (as above).

CachedKids (hash ref)

For a database handle, returns a reference to the cache (hash) of statement handles created by the prepare_cached method. For a driver handle, it would return a reference to the cache (hash) of statement handles created by the (not yet implemented) connect_cached method.

CompatMode (boolean, inherited)

Used by emulation layers (such as Oraperl) to enable compatible behaviour in the underlying driver (e.g., DBD::Oracle) for this handle. Not normally set by application code.

InactiveDestroy (boolean)

This attribute can be used to disable the database related effect of DESTROY'ing a handle (which would normally close a prepared statement or disconnect from the database etc). It is specifically designed for use in UNIX applications which 'fork' child processes. Either the parent or the child process, but not both, should set InactiveDestroy on all their handles. For a database handle, this attribute does not disable an explicit call to the disconnect method, only the implicit call from DESTROY.

PrintError (boolean, inherited)

This attribute can be used to force errors to generate warnings (using warn) in addition to returning error codes in the normal way. When set on, any method which results in an error occuring will cause the DBI to effectively do a warn(``$class $method failed $DBI::errstr'') where $class is the driver class and $method is the name of the method which failed. E.g., 

  DBD::Oracle::db prepare failed: ... error text here ...

By default DBI->connect sets PrintError on (except for old-style connect usage, see connect for more details).

If desired, the warnings can be caught and processed using a $SIG{__WARN__} handler or modules like CGI::ErrorWrap.

RaiseError (boolean, inherited)

This attribute can be used to force errors to raise exceptions rather than simply return error codes in the normal way. It defaults to off. When set on, any method which results in an error occuring will cause the DBI to effectively do a die(``$class $method failed $DBI::errstr'') where $class is the driver class and $method is the name of the method which failed. E.g., 

  DBD::Oracle::db prepare failed: ... error text here ...

If PrintError is also on then the PrintError is done before the RaiseError unless no __DIE__ handler has been defined, in which case PrintError is skipped since the die will print the message.

If you want to temporarily turn RaiseError off (inside a library function that is likely to fail for example), the recommended way is like this: 

  {
    local $h->{RaiseError} = 0 if $h->{RaiseError};
    ...
  }

The original value will automatically and reliably be restored by perl regardless of how the block is exited. The ... if $h-{RaiseError}> is optional but makes the code slightly faster in the common case. The same logic applies to other attributes, including RaiseError.

Sadly this doesn't work for perl versions upto and including 5.004_04. For backwards compatibility could just use eval { ... } instead.

ChopBlanks (boolean, inherited)

This attribute can be used to control the trimming of trailing space characters from fixed width character (CHAR) fields. No other field types are affected, even where field values have trailing spaces.

The default is false (it is possible that that may change). Applications that need specific behaviour should set the attribute as needed. Emulation interfaces should set the attribute to match the behaviour of the interface they are emulating.

Drivers are not required to support this attribute but any driver which does not must arrange to return undef as the attribute value.

LongReadLen (unsigned integer, inherited)

This attribute may be used to control the maximum length of 'long' ('blob', 'memo' etc.) fields which the driver will read from the database automatically when it fetches each row of data.

A value of 0 means don't automatically fetch any long data (fetch should return undef for long fields when LongReadLen is 0).

The default is typically 0 (zero) bytes but may vary between drivers. Most applications fetching long fields will set this value to slightly larger than the longest long field value which will be fetched.

Changing the value of LongReadLen for a statement handle after it's been prepare()'d will typically have no effect so it's usual to set LongReadLen on the $dbh before calling prepare.

The LongReadLen attribute only relates to fetching/reading long values it is not involved in inserting/updating them.

See LongTruncOk about truncation behaviour.

LongTruncOk (boolean, inherited)

This attribute may be used to control the effect of fetching a long field value which has been truncated (typically because it's longer than the value of the LongReadLen attribute).

By default LongTruncOk is false and fetching a truncated long value will cause the fetch to fail. (Applications should always take care to check for errors after a fetch loop in case an error, such as a divide by zero or long field truncation, caused the fetch to terminate prematurely.)

If a fetch fails due to a long field truncation when LongTruncOk is false, many drivers will allow you to continue fetching further rows.

See also LongReadLen.

private_*

The DBI provides a way to store extra information in a DBI handle as 'private' attributes. The DBI will allow you to store and retreive any attribute which has a name starting with 'private_'. It is strongly recommended that you use just one private attribute (e.g., use a hash ref) and give it a long and unambiguous name that includes the module or application that the attribute relates to (e.g., 'private_YourFullModuleName_thingy').

DBI DATABASE HANDLE OBJECTS

Database Handle Methods

selectrow_array 

  @row_ary = $dbh->selectrow_array($statement);
  @row_ary = $dbh->selectrow_array($statement, \%attr);
  @row_ary = $dbh->selectrow_array($statement, \%attr, @bind_values);

This utility method combines prepare, execute and fetchrow_array into a single call. If called in a list context it returns the first row of data from the statement. If called in a scalar context it returns the first field of the first row. The $statement parameter can be a previously prepared statement handle in which case the prepare is skipped.

In any method fails, and RaiseError is not set, selectrow_array will return an empty list (or undef in scalar context). 

#!/usr/bin/perl -w
use DBI;
use strict;

my $dbh = DBI->connect("DBI:DBMaker:DBSAMPLE","SYSADM","")
          or die "Unable to connect to Database: $DBI::errstr\n";
$dbh->do("CREATE TABLE t1(i int, c varchar(10))");
$dbh->do("INSERT INTO t1 VALUES(1,'aaa')");
$dbh->do("INSERT INTO t1 VALUES(2,'bbb')");

my @ary = $dbh->selectrow_array("select * from t1");
foreach my $i (@ary) {
 print "'$i',";
}
print "\n\n";

@ary = $dbh->selectrow_array("select * from t1 where c like ?",
  undef, "b%");
foreach my $i (@ary) {
 print "'$i',";
}
print "\n";
$dbh->do("DROP TABLE t1");
$dbh->disconnect;
selectall_arrayref 

  $ary_ref = $dbh->selectall_arrayref($statement);
  $ary_ref = $dbh->selectall_arrayref($statement, \%attr);
  $ary_ref = $dbh->selectall_arrayref($statement, \%attr, @bind_values);

This utility method combines prepare, execute and fetchall_arrayref into a single call. The $statement parameter can be a previously prepared statement handle in which case the prepare is skipped.

In any method fails, and RaiseError is not set, selectall_arrayref will return undef.

prepare 

  $sth = $dbh->prepare($statement)          || die $dbh->errstr;
  $sth = $dbh->prepare($statement, \%attr)  || die $dbh->errstr;

Prepares a single statement for later execution by the database engine and returns a reference to a statement handle object.

The returned statement handle can be used to get attributes of the statement and invoke the execute method. See Statement Handle Methods.

Note that prepare should never execute a statement, even if it is not a select statement, it only prepares it for execution. (Having said that, some drivers, notably Oracle, will execute data definition statements such as create/drop table when they are prepared. In practice this is rarely a problem.)

Drivers for engines which don't have the concept of preparing a statement will typically just store the statement in the returned handle and process it when $sth->execute is called. Such drivers are likely to be unable to give much useful information about the statement, such as $sth->{NUM_OF_FIELDS}, until after $sth->execute has been called. Portable applications should take this into account.

In general DBI drivers do not parse the contents of the statement (other than simply counting any Placeholders). The statement is passed directly to the database engine (sometimes known as pass-thru mode). This has advantages and disadvantages. On the plus side, you can access all the functionality of the engine being used. On the downside, you're limited if using a simple engine and need to take extra care if attempting to write applications to be portable between engines.

Some command-line SQL tools use statement terminators, like a semicolon, to indicate the end of a statement. Such terminators should not be used with the DBI.

prepare_cached 

  $sth = $dbh->prepare_cached($statement)          || die $dbh->errstr;
  $sth = $dbh->prepare_cached($statement, \%attr)  || die $dbh->errstr;

Like prepare except that the statement handled returned will be stored in a hash associated with the $dbh. If another call is made to prepare_cached with the same parameter values then the corresponding cached $sth will be returned (and the database server will not be contacted).

This cacheing can be useful in some applications but it can also cause problems and should be used with care. Currently a warning will be generated if the cached $sth being returned is active (i.e., is a select that may still have data to be fetched).

The cache can be accessed (and cleared) via the CachedKids attribute.

do 

  $rc  = $dbh->do($statement)           || die $dbh->errstr;
  $rc  = $dbh->do($statement, \%attr)   || die $dbh->errstr;
  $rv  = $dbh->do($statement, \%attr, @bind_values) || ...

Prepare and execute a single statement. Returns the number of rows affected (-1 if not known or not available) or undef on error.

This method is typically most useful for non-select statements which either cannot be prepared in advance (due to a limitation of the driver) or which do not need to be executed repeatedly. It should not be used for select statements.

The default do method is logically similar to: 

  sub do {
      my($dbh, $statement, $attr, @bind_values) = @_;
      my $sth = $dbh->prepare($statement, $attr) or return undef;
      $sth->execute(@bind_values) or return undef;
      my $rows = $sth->rows;
      ($rows == 0) ? "0E0" : $rows; # always return true if no error
  }

Example: 

  my $rows_deleted = $dbh->do(q{
      delete from table
      where status = ?
  }, undef, 'DONE') || die $dbh->errstr;

Using placeholders and @bind_values with the do method can be useful because it avoids the need to correctly quote any variables in the $statement.

The q{...} style quoting used in this example avoids clashing with quotes that may be used in the SQL statement. Use the double-quote like qq{...} operator if you want to interpolate variables into the string. See perlop for more details.

commit 

  $rc  = $dbh->commit     || die $dbh->errstr;

Commit (make permanent) the most recent series of database changes if the database supports transactions.

If the database supports transactions and AutoCommit is on then the commit should issue a ``commit ineffective with AutoCommit'' warning.

See also Transactions.

rollback 

  $rc  = $dbh->rollback   || die $dbh->errstr;

Roll-back (undo) the most recent series of uncommitted database changes if the database supports transactions.

If the database supports transactions and AutoCommit is on then the rollback should issue a ``rollback ineffective with AutoCommit'' warning.

See also Transactions.

disconnect 

  $rc = $dbh->disconnect  || warn $dbh->errstr;

Disconnects the database from the database handle. Typically only used before exiting the program. The handle is of little use after disconnecting.

The transaction behaviour of the disconnect method is, sadly, undefined. Some database systems (such as Oracle and Ingres) will automatically commit any outstanding changes, but others (such as Informix) will rollback any outstanding changes. Applications should explicitly call commit or rollback before calling disconnect.

The database is automatically disconnected (by the DESTROY method) if still connected when there are no longer any references to the handle. The DESTROY method for each driver should explicitly call rollback to undo any uncommitted changes. This is vital behaviour to ensure that incomplete transactions don't get committed simply because Perl calls DESTROY on every object before exiting. Also, do not rely on the order of object destruction during 'global destruction', it is undefined.

If you disconnect from a database while you still have active statement handles you will get a warning. The statement handles should either be cleared (destroyed) before disconnecting or the finish method called on each one. 

#!/usr/bin/perl -w
use DBI;
use strict;

my $dbh = DBI->connect("DBI:DBMaker:DBSAMPLE","SYSADM","",
          {AutoCommit=>0})
          or die "Unable to connect to Database: $DBI::errstr\n";
$dbh->do("CREATE TABLE t1 (id int, name varchar(10))")
          or warn "Unable to create table t1";
my $sth = $dbh->prepare("INSERT INTO t1 values(?,?)")
          or warn "Cannot prepare\n";
for (my $i=0; $i<1000; $i++) {
  $sth->execute($i, 'ABC'.$i)
        or die "Unable to execute query: $dbh->errstr\n";
  print "$i\n" if ($i%100==0);
}
$dbh->commit;
$dbh->do("DROP TABLE t1");
$dbh->disconnect;
ping 

  $rc = $dbh->ping;

Attempts to determine, in a reasonably efficient way, if the database server is still running and the connection to it is still working.

The default implementation currently always returns true without actually doing anything. Individual drivers should implement this function in the most suitable manner for their database engine.

Very few applications would have any use for this method. See the specialist Apache::DBI module for one example usage.

table_info *NEW*

Warning: This method is experimental and may change or disappear. 

  $sth = $dbh->table_info;

Returns an active statement handle that can be used to fetch information about tables and views that exist in the database.

The handle has at least the following fields in the order show below. Other fields, after these, may also be present.

TABLE_QUALIFIER: Table qualifier identifier. NULL (undef) if not applicable to data source (usually the case). Empty if not applicable to the table.

TABLE_OWNER: Table owner identifier. NULL (undef) if not applicable to data source. Empty if not applicable to the table.

TABLE_NAME: Table name.

TABLE_TYPE: One of the following: ``TABLE'', ``VIEW'', ``SYSTEM TABLE'', ``GLOBAL TEMPORARY'', ``LOCAL TEMPORARY'', ``ALIAS'', ``SYNONYM'' or a data source specific type identifier.

REMARKS: A description of the table. May be NULL (undef).

Note that table_info might not return records for all tables. Applications can use any valid table regardless of whether it's returned by table_info. See also tables.

tables *NEW*

Warning: This method is experimental and may change or disappear. 

  @names = $dbh->tables;

Returns a list of table and view names. This list should include all tables which can be used in a select statement without further qualification. That typically means all the tables and views owned by the current user and all those accessible via public synonyms/aliases (excluding non-metadata system tables and views).

Note that table_info might not return records for all tables. Applications can use any valid table regardless of whether it's returned by tables. See also table_info.

type_info_all *NEW*

Warning: This method is experimental and may change or disappear. 

  $type_info_all = $dbh->type_info_all;

Returns a reference to an array which holds information about each data type variant supported by the database and driver.

The first item is a reference to a hash of Name => Index pairs. The following items are references to arrays, one per supported data type variant. The leading hash defines the names and order of the fields within the following list of arrays. For example: 

  $type_info_all = [
    {   TYPE_NAME         => 0,
        DATA_TYPE         => 1,
        PRECISION         => 2,
        LITERAL_PREFIX    => 3,
        LITERAL_SUFFIX    => 4,
        CREATE_PARAMS     => 5,
        NULLABLE          => 6,
        CASE_SENSITIVE    => 7,
        SEARCHABLE        => 8,
        UNSIGNED_ATTRIBUTE=> 9,
        MONEY             => 10,
        AUTO_INCREMENT    => 11,
        LOCAL_TYPE_NAME   => 12,
        MINIMUM_SCALE     => 13,
        MAXIMUM_SCALE     => 14,
    },
    [ 'VARCHAR', SQL_VARCHAR,
        undef, "'","'", undef,0, 1,1,0,0,0,undef,1,255
    ],
    [ 'INTEGER', SQL_INTEGER,
        undef,  "", "", undef,0, 0,1,0,0,0,undef,0,  0
    ],
  ];

Note that more than one row may have the same value in the DATA_TYPE field.

This method is not normally used directly. The type_info method provides a more useful interface to the data.

The meaning of the fields is described in the documentation for the type_info method.

type_info *NEW*

Warning: This method is experimental and may change or disappear. 

  @type_info = $dbh->type_info($data_type);

Returns a list of hash references holding information about one or more variants of $data_type (or a type reasonably compatible with it).

If $data_type is SQL_ALL_TYPES then the list will contain hashes for all data type variants supported by the database and driver.

The keys of the hash follow the same letter case conventions as the rest of the DBI (see Naming Conventions and Name Space). The following items should exist:

TYPE_NAME (string)

Data type name for use in CREATE TABLE statements etc.

DATA_TYPE (integer)

SQL data type number.

PRECISION (integer)

The maximum precision of the data type. NULL (undef) is returned for data types where this is not applicable.

LITERAL_PREFIX (string)

Characters used to prefix a literal. Typically ``''' for characters, possibly ``0x'' for binary values passed as hex. NULL (undef) is returned for data types where this is not applicable.

LITERAL_SUFFIX (string)

Characters used to suffix a literal. Typically ``''' for characters. NULL (undef) is returned for data types where this is not applicable.

CREATE_PARAMS (string)

Parameters for a data type definition. For example, CREATE_PARAMS for a DECIMAL would be ``precision,scale''. For a VARCHAR it would be ``max length''. NULL (undef) is returned for data types where this is not applicable.

NULLABLE (integer)

Indicates whether the data type accepts a NULL value: 0 = no, 1 = yes, 2 = unknown.

CASE_SENSITIVE (boolean)

Indicates whether the data type is case sensitive in collations and comparisons.

SEARCHABLE (integer)

Indicates how the data type can be used in a WHERE clause: 

  0 - cannot be used in a WHERE clause
  1 - only with a LIKE predicate
  2 - all comparison operators except LIKE
  3 - can be used in a WHERE clause with any comparison operator
UNSIGNED_ATTRIBUTE (boolean)

Indicates whether the data type is unsigned. NULL (undef) is returned for data types where this is not applicable.

MONEY (boolean)

Indicates whether the data type is a money data type. NULL (undef) is returned for data types where this is not applicable.

AUTO_INCREMENT (boolean)

Indicates whether the data type is autoincrementing. NULL (undef) is returned for data types where this is not applicable.

LOCAL_TYPE_NAME (string)

Localised version of the TYPE_NAME for use in dialogue with users. NULL (undef) is returned if a localised name is not available (in which case TYPE_NAME should be used).

MINIMUM_SCALE (integer)

The minimum scale of the data type. If a data type has a fixed scale then MAXIMUM_SCALE holds the same value. NULL (undef) is returned for data types where this is not applicable.

MAXIMUM_SCALE (integer)

The maximum scale of the data type. If a data type has a fixed scale then MINIMUM_SCALE holds the same value. NULL (undef) is returned for data types where this is not applicable.

quote 

  $sql = $dbh->quote($value);
  $sql = $dbh->quote($value, $data_type);

Quote a string literal for use as a literal value in an SQL statement by escaping any special characters (such as quotation marks) contained within the string and adding the required type of outer quotation marks. 

  $sql = sprintf "select foo from bar where baz = %s",
                $dbh->quote("Don't\n");

For most database types quote would return 'Don''t' (including the outer quotation marks).

An undefined $value value will be returned as the string NULL (without quotation marks).

If $data_type is supplied it is used to try to determine the required quoting behaviour by using the information returned by type_info. As a special case, the standard numeric types are optimised to return $value without calling type_info.

Quote may not be able to deal with all possible input (such as binary data) and is not related in any way with escaping or quoting shell meta-characters. There is no need to quote values being used with Placeholders and Bind Values.

Database Handle Attributes

This section describes attributes specific to database handles.

Changes to these database handle attributes do not affect any other existing or future database handles.

Attempting to set or get the value of an unknown attribute is fatal, except for private driver specific attributes (which all have names starting with a lowercase letter).

Example: 

  $h->{AutoCommit} = ...;       # set/write
  ... = $h->{AutoCommit};       # get/read
AutoCommit (boolean)

If true then database changes cannot be rolled-back (undone). If false then database changes automatically occur within a 'transaction' which must either be committed or rolled-back using the commit or rollback methods.

Drivers should always default to AutoCommit mode. (An unfortunate choice forced on the DBI by ODBC and JDBC conventions.)

Attempting to set AutoCommit to an unsupported value is a fatal error. This is an important feature of the DBI. Applications which need full transaction behaviour can set $dbh->{AutoCommit}=0 (or via connect) without having to check the value was assigned okay.

For the purposes of this description we can divide databases into three categories: 

  Database which don't support transactions at all.
  Database in which a transaction is always active.
  Database in which a transaction must be explicitly started ('BEGIN WORK').

* Database which don't support transactions at all

For these databases attempting to turn AutoCommit off is a fatal error. Commit and rollback both issue warnings about being ineffective while AutoCommit is in effect.

* Database in which a transaction is always active

These are typically mainstream commercial relational databases with 'ANSI standard' transaction behaviour.

If AutoCommit is off then changes to the database won't have any lasting effect unless commit is called (but see also disconnect). If rollback is called then any changes since the last commit are undone.

If AutoCommit is on then the effect is the same as if the DBI were to have called commit automatically after every successful database operation. In other words, calling commit or rollback explicitly while AutoCommit is on would be ineffective because the changes would have already been commited.

Changing AutoCommit from off to on should issue a commit in most drivers.

Changing AutoCommit from on to off should have no immediate effect.

For databases which don't support a specific auto-commit mode, the driver has to commit each statement automatically using an explicit COMMIT after it completes successfully (and roll it back using an explicit ROLLBACK if it fails). The error information reported to the application will correspond to the statement which was executed, unless it succeeded and the commit or rollback failed.

* Database in which a transaction must be explicitly started

For these database the intention is to have them act like databases in which a transaction is always active (as described above).

To do this the DBI driver will automatically begin a transaction when AutoCommit is turned off (from the default on state) and will automatically begin another transaction after a commit or rollback.

In this way, the application does not have to treat these databases as a special case. 

#!/usr/bin/perl -w
use DBI;
use strict;

my $dbh = DBI->connect("DBI:DBMaker:DBSAMPLE","SYSADM","")
          or die "Unable to connect to Database: $DBI::errstr\n";
$dbh->do("CREATE TABLE t1 (id int, name varchar(10))")
          or warn "Unable to create table t1";
my $sth = $dbh->prepare("INSERT INTO t1 values(?,?)")
          or warn "Cannot prepare\n";

$dbh->{AutoCommit}=0;
printf "Commit mode %s\n", $dbh->{AutoCommit};
for (my $i=0; $i<1000; $i++) {
  $sth->execute($i, 'A'.$i)
        or die "Unable to execute query: $dbh->errstr\n";
  print "$i\n" if ($i%100==0);
}
$dbh->commit;

$dbh->{AutoCommit}=1;
printf "Commit mode %s\n", $dbh->{AutoCommit};
for (my $i=0; $i<1000; $i++) {
  $sth->execute($i, 'B'.$i)
        or die "Unable to execute query: $dbh->errstr\n";
  print "$i\n" if ($i%100==0);
}

$dbh->disconnect;
Name (string)

Holds the 'name' of the database. Usually (and recommended to be) the same as the ``dbi:DriverName:...'' string used to connect to the database but with the leading ``dbi:DriverName:'' removed. 

#!/usr/bin/perl -w
use DBI;
use strict;

my $dbh = DBI->connect("DBI:DBMaker:DBSAMPLE","SYSADM","")
          or die "Unable to connect to Database: $DBI::errstr\n";
print $dbh->{Name};
$dbh->disconnect;
RowCacheSize (integer) *NEW*

A hint to the driver indicating the size of local row cache the application would like the driver to use for future select statements. If a row cache is not implemented then setting RowCacheSize is ignored and getting the value returns undef.

Some RowCacheSize values have special meaning: 

  0 - Automatically determine a reasonable cache size for each select
  1 - Disable the local row cache
 >1 - Cache this many rows
 <0 - Cache as many rows fit into this much memory for each select.

Note that large cache sizes may require very large amount of memory (cached rows * maximum size of row) and that a large cache will cause a longer delay for the first fetch and when the cache needs refilling.

See also RowsInCache statement handle attribute.

DBI STATEMENT HANDLE OBJECTS

Statement Handle Methods

bind_param 

  $rc = $sth->bind_param($p_num, $bind_value)  || die $sth->errstr;
  $rv = $sth->bind_param($p_num, $bind_value, \%attr)     || ...
  $rv = $sth->bind_param($p_num, $bind_value, $bind_type) || ...

The bind_param method can be used to bind (assign/associate) a value with a placeholder embedded in the prepared statement. Placeholders are indicated with question mark character (?). For example: 

  $dbh->{RaiseError} = 1;        # save having to check each method call
  $sth = $dbh->prepare("select name, age from people where name like ?");
  $sth->bind_param(1, "John%");  # placeholders are numbered from 1
  $sth->execute;
  DBI::dump_results($sth);

Note that the ? is not enclosed in quotation marks even when the placeholder represents a string. Some drivers also allow :1, :2 etc and :name style placeholders in addition to ? but their use is not portable.

Some drivers do not support placeholders.

With most drivers placeholders can't be used for any element of a statement that would prevent the database server validating the statement and creating a query execution plan for it. For example: 

  "select name, age from ?"         # wrong
  "select name, ?   from people"    # wrong

Also, placeholders can only represent single scalar values, so this statement, for example, won't work as expected for more than one value: 

  "select name, age from people where name in (?)"    # wrong

The \%attr parameter can be used to specify the data type the placeholder should have. Typically the driver is only interested in knowing if the placeholder should be bound as a number or a string. 

  $sth->bind_param(1, $value, { TYPE => SQL_INTEGER });

As a short-cut for this common case, the data type can be passed directly inplace of the attr hash reference. This example is equivalent to the one above: 

  $sth->bind_param(1, $value, SQL_INTEGER);

The TYPE cannot be changed after the first bind_param call (but it can be left unspecified, in which case it defaults to the previous value). The TYPE value indicated the standard non-driver-specific type for this parameter. To specify the driver-specific type the driver may support a driver-specific attribute, e.g., { ora_type => 97 }.

Perl only has string and number scalar data types. All database types that aren't numbers are bound as strings and must be in a format the database will understand.

Undefined values or undef are be used to indicate null values. 

#!/usr/bin/perl -w
use DBI;
use strict;

my $dbh = DBI->connect("DBI:DBMaker:DBSAMPLE","SYSADM","")
          or die "Unable to connect to Database: $DBI::errstr\n";

$dbh->do("CREATE TABLE employee (".
         "id int, name varchar(10), phone varchar(10))")
          or warn "Unable to create table t1";

my $sth = $dbh->prepare("INSERT INTO employee values(?,?,?)")
          or warn "Cannot prepare\n";
my @names = ( "Larry", "Tim",   "Randal", "Doug",  "Trent" );
my @phone = ( "11111", "22222", "33333",  "44444", "55555" );
for (my $i=0; $i<= $#names; $i++) {
  $sth->bind_param(1, $i);
  $sth->bind_param(2, $names[$i]);
  $sth->bind_param(3, $phone[$i]);
  $sth->execute or warn "$DBI::errstr";
}
$dbh->commit;

my @alpha = ('A'..'Z');
$sth = $dbh->prepare("SELECT * from employee where name like :user");
for (my $i=0; $i<26; $i++) {
  $sth->bind_param("user", "$alpha[$i]%");
  $sth->execute;
  print "_____________________\n";
  printf "User %s:\n %-10s%s\n", $alpha[$i], 'Name', 'Phone';
  print "_____________________\n";
  while(my $row = $sth->fetchrow_arrayref) {
    my($id, $n, $p) = @$row;
    printf " %-10s%s\n", $n, $p;
  }
  print "\n";
}

$sth->finish;
$dbh->disconnect;
bind_param_inout 

  $rc = $sth->bind_param_inout($p_num, \$bind_value, $max_len)  || die $sth->errstr;
  $rv = $sth->bind_param_inout($p_num, \$bind_value, $max_len, \%attr)     || ...
  $rv = $sth->bind_param_inout($p_num, \$bind_value, $max_len, $bind_type) || ...

This method acts like bind_param but also enables values to be output from (updated by) the statement. The statement is typically a call to a stored procedure. The $bind_value must be passed as a reference to the actual value to be used.

Note that unlike bind_param, the $bind_value variable is not read when bind_param_inout is called. Instead, the value in the variable is read at the time execute is called.

The additional $max_len parameter specifies the minimum amount of memory to allocate to $bind_value for the new value. If the value is too big to fit then the execute should fail. If unsure what value to use, pick a generous length larger than the longest value that would ever be returned. The only cost of using a very large value is memory.

It is expected that few drivers will support this method. The only driver currently known to do so is DBD::Oracle (DBD::ODBC may support it in a future release). Therefore it should not be used for database independent applications.

execute 

  $rv = $sth->execute                || die $sth->errstr;
  $rv = $sth->execute(@bind_values)  || die $sth->errstr;

Perform whatever processing is necessary to execute the prepared statement. An undef is returned if an error occurs, a successful execute always returns true regardless of the number of rows affected (even if it's zero, see below). It is always important to check the return status of execute (and most other DBI methods) for errors.

For a non-select statement, execute returns the number of rows affected (if known). If no rows were affected then execute returns ``0E0'' which Perl will treat as 0 but will regard as true. Note that it is not an error for no rows to be affected by a statement. If the number of rows affected is not known then execute returns -1.

For select statements execute simply 'starts' the query within the Engine. Use one of the fetch methods to retreive the data after calling execute. The execute method does not return the number of rows that will be returned by the query (because most Engines can't tell in advance), it simply returns a true value.

If any arguments are given then execute will effectively call bind_param for each value before executing the statement. Values bound in this way are usually treated as SQL_VARCHAR types unless the driver can determine the correct type (which is rare) or bind_param (or bind_param_inout) has already been used to specify the type. 

#!/usr/bin/perl -w
use DBI;
use strict;

my $dbh = DBI->connect("DBI:DBMaker:DBSAMPLE","SYSADM","")
          or die "Unable to connect to Database: $DBI::errstr\n";

my $sth = $dbh->prepare("INSERT INTO employee values(?,?,?)")
          or warn "Cannot prepare\n";
my @names = ( "Larry", "Tim",   "Randal", "Doug",  "Trent" );
my @phone = ( "11111", "22222", "33333",  "44444", "55555" );
for (my $i=0; $i<= $#names; $i++) {
  $sth->execute($i,$names[$i],$phone[$i]) or warn "$DBI::errstr";
}
$dbh->commit;
$sth->finish;
$dbh->disconnect;
fetchrow_arrayref 

  $ary_ref = $sth->fetchrow_arrayref;
  $ary_ref = $sth->fetch;    # alias

Fetches the next row of data and returns a reference to an array holding the field values. Null field values are returned as undef. This is the fastest way to fetch data, particularly if used with $sth->bind_columns.

If there are no more rows or an error occurs fetchrow_arrayref returns undef (you should check $sth->err afterwards or use RaiseError).

Note that currently the same array ref will be returned for each fetch so don't store the ref and then use it after a later fetch. 

#!/usr/bin/perl -w
use DBI;
use strict;

my $dbh = DBI->connect("DBI:DBMaker:DBSAMPLE","SYSADM","")
          or die "Unable to connect to Database: $DBI::errstr\n";

my $sth = $dbh->prepare("SELECT * from employee");
$sth->execute;
printf " %-10s%s\n", 'Name', 'Phone';
print "_____________________\n";
while(my $row = $sth->fetchrow_arrayref) {
  printf " %-10s%s\n", $row->[1], $row->[2];
}
$sth->finish;
$dbh->disconnect;
fetchrow_array 

 @ary = $sth->fetchrow_array;

An alternative to fetchrow_arrayref. Fetches the next row of data and returns it as an array holding the field values. Null values are returned as undef.

If there are no more rows or an error occurs fetchrow_array returns an empty list (you should check $sth->err afterwards or use RaiseError). 

#!/usr/bin/perl -w
use DBI;
use strict;

my $dbh = DBI->connect("DBI:DBMaker:DBSAMPLE","SYSADM","")
          or die "Unable to connect to Database: $DBI::errstr\n";

my $sth = $dbh->prepare("SELECT * from employee order by phone");
$sth->execute;
printf " %-10s%s\n", 'Name', 'Phone';
print "_____________________\n";
while(my @row = $sth->fetchrow_array) {
  printf " %-10s%s\n", $row[1], $row[2];
}
$sth->finish;
$dbh->disconnect;
fetchrow_hashref 

 $hash_ref = $sth->fetchrow_hashref;
 $hash_ref = $sth->fetchrow_hashref($name);

An alternative to fetchrow_arrayref. Fetches the next row of data and returns it as a reference to a hash containing field name and field value pairs. Null values are returned as undef.

If there are no more rows or an error occurs fetchrow_hashref returns undef (you should check $sth->err afterwards or use RaiseError).

The optional $name parameter specifies the name of the statement handle attribute to use to get the field names. It defaults to 'NAME'.

The keys of the hash are the same names returned by $sth->{$name}. If more than one field has the same name there will only be one entry in the returned hash for those fields.

Note that using fetchrow_hashref is currently not portable between databases because different databases return fields names with different letter cases (some all uppercase, some all lower, and some return the letter case used to create the table). This will be addressed in a future version of the DBI.

Because of the extra work fetchrow_hashref and perl have to perform it is not as efficient as fetchrow_arrayref or fetchrow_array and is not recommended where performance is very important. Currently a new hash reference is returned for each row. This is likely to change in the future so don't rely on it. 

#!/usr/bin/perl -w
use DBI;
use strict;

my $dbh = DBI->connect("DBI:DBMaker:DBSAMPLE","SYSADM","")
          or die "Unable to connect to Database: $DBI::errstr\n";

my $sth = $dbh->prepare("SELECT * from employee order by name");
$sth->execute;
printf " %-10s%s\n", 'Name', 'Phone';
print "_____________________\n";
while(my $row = $sth->fetchrow_hashref) {
  printf " %-10s%s\n", $row->{name}, $row->{phone};
}
$sth->finish;
$dbh->disconnect;
fetchall_arrayref 

  $tbl_ary_ref = $sth->fetchall_arrayref;
  $tbl_ary_ref = $sth->fetchall_arrayref( $slice_array_ref );
  $tbl_ary_ref = $sth->fetchall_arrayref( $slice_hash_ref  );

The fetchall_arrayref method can be used to fetch all the data to be returned from a prepared and executed statement handle. It returns a reference to an array which contains one reference per row. If there are no rows to return, fetchall_arrayref returns a reference to an empty array. If an error occurs fetchall_arrayref returns the data fetched thus far (you should check $sth->err afterwards or use RaiseError).

When passed an array reference, fetchall_arrayref uses fetchrow_arrayref to fetch each row as an array ref. If the parameter array is not empty then it is used as a slice to select individual columns by index number.

With no parameters, fetchall_arrayref acts as if passed an empty array ref.

When passed a hash reference, fetchall_arrayref uses fetchrow_hashref to fetch each row as a hash ref. If the parameter hash is not empty then it is used as a slice to select individual columns by name. The names should be lower case regardless of the letter case in $sth->{NAME}. The values of the hash should be set to 1.

For example, to fetch just the first column of every row you can use: 

  $tbl_ary_ref = $sth->fetchall_arrayref([0]);

To fetch the second to last and last column of every row you can use: 

  $tbl_ary_ref = $sth->fetchall_arrayref([-2,-1]);

To fetch only the fields called foo and bar of every row you can use: 

  $tbl_ary_ref = $sth->fetchall_arrayref({ foo=>1, bar=>1 });

The first two examples return a ref to an array of array refs. The last returns a ref to an array of hash refs. 

#!/usr/bin/perl -w
use DBI;
use strict;

my $dbh = DBI->connect("DBI:DBMaker:DBSAMPLE","SYSADM","")
          or die "Unable to connect to Database: $DBI::errstr\n";

my $sth = $dbh->prepare("SELECT * from employee");
$sth->execute;
my $tb = $sth->fetchall_arrayref([1,-1]);
printf " %-10s%s\n", 'Name', 'Phone';
print "_____________________\n";
my $i = 0;
while(defined($tb->[$i][0])) {
  printf " %-10s%s\n", $tb->[$i][0], $tb->[$i][1];
  $i++;
}
$sth->finish;
$dbh->disconnect;
finish 

  $rc  = $sth->finish;

Indicates that no more data will be fetched from this statement handle before it is either executed again or destroyed. It is rarely needed but can sometimes be helpful in order to allow the server to free up resources currently being held (such as sort buffers).

When all the data has been fetched from a select statement the driver should automatically call finish for you. So you should not normally need to call it explicitly.

Consider a query like 

  SELECT foo FROM table WHERE bar=? ORDER BY foo

where you want to select just the first (smallest) foo value from a large table. When executed the database server will have to use temporary buffer space to store the sorted rows. If, after executing the handle and selecting one row, the handle won't be re-executed for some time or not at all, the finish method can be used to tell the server that the buffer space can be freed.

Calling finish resets the Active attribute for the statement. It may also make some statement handle attributes, like NAME and TYPE etc., unavailable if they have not already been accessed (and thus cached).

The finish method does not affect the transaction status of the session. It has nothing to do with transactions. It's mostly an internal 'housekeeping' method that is rarely needed. There's no need to call finish if you're about to destroy or re-execute the statement handle. See also disconnect and the Active attribute.

rows 

  $rv = $sth->rows;

Returns the number of rows affected by the last database altering command, or -1 if not known or not available.

Generally you can only rely on a row count after a do or non-select execute (for some specific operations like update and delete) or after fetching all the rows of a select statement.

For select statements it is generally not possible to know how many rows will be returned except by fetching them all. Some drivers will return the number of rows the application has fetched so far but others may return -1 until all rows have been fetched. So use of the rows method with select statements is not recommended. 

#!/usr/bin/perl -w
use DBI;
use strict;

my $dbh = DBI->connect("DBI:DBMaker:DBSAMPLE","SYSADM","")
          or die "Unable to connect to Database: $DBI::errstr\n";

my $sth = $dbh->prepare("SELECT * from employee");
$sth->execute;
my $rc = $sth->rows;
print "Before fetch rowcount: $rc\n";
my $tb = $sth->fetchall_arrayref;
$rc = $sth->rows;
print "After fetch rowcount: $rc\n";

$sth = $dbh->prepare("UPDATE employee set phone='00000' where id>3");
$sth->execute;
$rc = $sth->rows;
print "After execute rowcount: $rc\n";
$sth->finish;
$dbh->disconnect;
bind_col 

  $rc = $sth->bind_col($column_number, \$var_to_bind);
  $rc = $sth->bind_col($column_number, \$var_to_bind, \%attr);

Binds an output column (field) of a select statement to a perl variable. You do not need to do this but it can be useful for some applications.

Whenever a row is fetched from the database the corresponding perl variable is automatically updated. There is no need to fetch and assign the values manually. This makes using bound variables very efficient. See bind_columns below for an example. Note that column numbers count up from 1.

The binding is performed at a very low level using perl aliasing so there is no extra copying taking place. So long as the driver uses the correct internal DBI call to get the array the fetch function returns, it will automatically support column binding.

For maximum portability between drivers, bind_col should be called after execute.

The bind_param method performs a similar function for input variables. See also Placeholders and Bind Values for more information.

bind_columns 

  $rc = $sth->bind_columns(\%attr, @list_of_refs_to_vars_to_bind);

Calls bind_col for each column of the select statement. bind_columns will die if the number of references does not match the number of fields. You do not need to do this but it can be useful for some applications.

For maximum portability between drivers, bind_columns should be called after execute.

For example: 

#!/usr/bin/perl -w
use DBI;
use strict;

my $dbh = DBI->connect("DBI:DBMaker:DBSAMPLE","SYSADM","")
          or die "Unable to connect to Database: $DBI::errstr\n";

$dbh->{RaiseError} = 1; # do this, or check every call for errors
my $sth = $dbh->prepare(q{ select name, phone from employee });
$sth->execute;
my ($name, $phone);

# Bind perl variables to columns:
my $rv = $sth->bind_columns(undef, \$name, \$phone);

# you can also use perl's \(...) syntax (see perlref docs):
#     $sth->bind_columns(undef, \($region, $sales));

printf " %-10s%s\n", 'Name', 'Phone';
print "_____________________\n";
# Column binding is the most efficient way to fetch data
while ($sth->fetch) {
  printf " %-10s%s\n", $name, $phone;
}

$sth->finish;
$dbh->disconnect;

Fetches all the rows from $sth, calls DBI::neat_list for each row and prints the results to $fh (defaults to STDOUT) separated by $lsep (default "\n"). $fsep defaults to ", " and $maxlen defaults to 35.

This method is designed as a handy utility for prototyping and testing queries. Since it uses neat_list which uses neat which formats and edits the string for reading by humans, it's not recomended for data transfer applications.

Statement Handle Attributes

This section describes attributes specific to statement handles. Most of these attributes are read-only.

Changes to these statement handle attributes do not affect any other existing or future statement handles.

Attempting to set or get the value of an unknown attribute is fatal, except for private driver specific attributes (which all have names starting with a lowercase letter).

Example: 

  ... = $h->{NUM_OF_FIELDS};    # get/read

Note that some drivers cannot provide valid values for some or all of these attributes until after $sth->execute has been called.

See also finish for the effect it may have on some attributes.

NUM_OF_FIELDS (integer, read-only)

Number of fields (columns) the prepared statement will return. Non-select statements will have NUM_OF_FIELDS == 0.

NUM_OF_PARAMS (integer, read-only)

The number of parameters (placeholders) in the prepared statement. See SUBSTITUTION VARIABLES below for more details.

NAME (array-ref, read-only)

Returns a reference to an array of field names for each column. The names may contain spaces but should not be truncated or have any trailing space. 

  print "First column name: $sth->{NAME}->[0]\n";
TYPE (array-ref, read-only) *NEW*

Returns a reference to an array of integer values for each column. The value indicates the data type of the corresponding column.

The values used correspond to the international standards (ANSI X3.135 and ISO/IEC 9075) which, in general terms means ODBC. Driver specific types which don't exactly match standard types should generally return the same values as an ODBC driver supplied by the makers of the database. That might include private type numbers the vendor has officially registered. See: 

  ftp://jerry.ece.umassd.edu/isowg3/dbl/SQL_Registry

Where there's no vendor supplied ODBC driver to be compatible with the DBI driver can use type numbers in the range now officially reserved for use by the DBI: -9999 to -9000.

All possible values for TYPE should have at least one entry in the output of the type_info_all method.

PRECISION (array-ref, read-only) *NEW*

Returns a reference to an array of integer values for each column. For nonnumeric columns the value generally refers to either the maximum length or the defined length of the column. For numeric columns the value refers to the maximum number of digits used by the data type (without considering a sign character or decimal point). Note that for floating point types (REAL, FLOAT, DOUBLE) the 'display size' can be up to 7 characters greater than the precision (for the sign + decimal point + the letter E + a sign + 2 or 3 digits).

SCALE (array-ref, read-only) *NEW*

Returns a reference to an array of integer values for each column. NULL (undef) values indicate columns where scale is not applicable.

NULLABLE (array-ref, read-only)

Returns a reference to an array indicating the possibility of each column returning a null: 0 = no, 1 = yes, 2 = unknown. 

  print "First column may return NULL\n" if $sth->{NULLABLE}->[0];
CursorName (string, read-only)

Returns the name of the cursor associated with the statement handle if available. If not available or the database driver does not support the "where current of ..."